Бэкап реестра Windows

Обсуждение программ nnCron и nnCron LITE

Бэкап реестра Windows

Postby Morituruz » Wed, 19 Jun 2013, 10:48

Резервное копирование реестра в стек архивов.
Для экспорта реестра в файлы *.reg используется встроенная в Windows программа reg.exe
Для копирования файлов реестра используется программа RegSaver.
Сайт: http://www.fridgesoft.de/regsaver.php

Для настройки задачи под свой компьютер нужно поменять время запуска + заполнить переменные после Action:
Code: Select all
#( registry_backup
\ 10:26 24.05.2013
Time: 20 0
NoLog
SingleInstance
CREATE registry_backup_path 256 ALLOT
CREATE regsaver_path 256 ALLOT
CREATE archiver_path 256 ALLOT
VARIABLE registry_limitation
Action:
\ ######## Настройки ########
\ Папка, куда складывать бэкапы:
S" d:\backup\serv_registry\" registry_backup_path PLACE
\ Путь до regsaver.exe:
S" c:\soft\regsaver\RegSaver.exe" EVAL-SUBST regsaver_path PLACE
\ Сколько дней храним бэкапы (всё, что старше удаляем):
30 registry_limitation !
\ Путь к архиватору 7z:
S" c:\Program Files\7-Zip\7z.exe" archiver_path PLACE


\ Сначала бэкап двоичных файлов реестра:
ShowNoActivate
START-APPW: %regsaver_path COUNT% %registry_backup_path COUNT%
ExitCodeProc
IF
   ERR-MSG: "Ошибка сохранения реестра: %ExitCodeProc N>S%"
   EXIT
ELSE   \ бэкап создан успешно
   registry_backup_path COUNT S" *" S+ FOR-FILES
      FOUND-FILENAME S" /(\d{4})(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)/" RE-MATCH
      IF
         \ переименовываем + сохраняем в переменную registry_backup_path. Последняя найденная папка будет самой новой:
         FOUND-FULLPATH 2DUP ONLYDIR
         " \%$1%-%$2%-%$3%_%$4%-%$5%-%$6%" S+ 2DUP registry_backup_path PLACE FRENAME
         GetLastError
         IF
            ERR-MSG: "Ошибка переименования папки с бэкапом реестра:%crlf 2DUP S+%%GetLastError WinErrorMessage% (%GetLastError N>S%)"
            EXIT
         THEN
      THEN
   ;FOR-FILES
THEN

\ экспорт в виде *.reg файлов (на всякий случай):
SWHide
START-APPW: reg export HKLM %registry_backup_path COUNT%\HKLM.reg
ExitCodeProc IF ERR-MSG: "Ошибка экспорта куста реестра HKLM: %ExitCodeProc N>S%" EXIT THEN
START-APPW: reg export HKCU %registry_backup_path COUNT%\HKCU.reg
ExitCodeProc IF ERR-MSG: "Ошибка экспорта куста реестра HKCU: %ExitCodeProc N>S%" EXIT THEN
START-APPW: reg export HKCR %registry_backup_path COUNT%\HKCR.reg
ExitCodeProc IF ERR-MSG: "Ошибка экспорта куста реестра HKCR: %ExitCodeProc N>S%" EXIT THEN
START-APPW: reg export HKU %registry_backup_path COUNT%\HKU.reg
ExitCodeProc IF ERR-MSG: "Ошибка экспорта куста реестра HKU: %ExitCodeProc N>S%" EXIT THEN
START-APPW: reg export HKCC %registry_backup_path COUNT%\HKCC.reg
ExitCodeProc IF ERR-MSG: "Ошибка экспорта куста реестра HKCC: %ExitCodeProc N>S%" EXIT THEN

\ архивируем бэкап в *.zip
START-APPW: "%archiver_path COUNT%" -tzip -ssw a -scsWIN "%registry_backup_path COUNT%.zip" %registry_backup_path COUNT%
ExitCodeProc
IF
   ERR-MSG: "Ошибка архивирования реестра: %ExitCodeProc N>S%"
   EXIT
ELSE
   \ заархивировали успешно, удаляем исходную папку
   registry_backup_path COUNT DIR-DELETE
   GetLastError 2 <>
   GetLastError 18 <>
   AND
   IF
      ERR-MSG: "Ошибка удаления папки с файлами реестра:%crlf 2DUP S+%%GetLastError WinErrorMessage% (%GetLastError N>S%)"
      EXIT
   THEN
THEN

\ удаляем файлы, у которых истёк срок хранения:
registry_backup_path COUNT ONLYDIR S" \*" S+ registry_limitation @ PURGE-OLDW
)#
User avatar
Morituruz
 
Posts: 727
Joined: Sun, 14 Oct 2007, 01:51

Re: Бэкап реестра Windows

Postby VoidVolker » Fri, 28 Jun 2013, 08:50

А смысле бэкапа реестра-то? Нынче весь раздел с виндой в легкую за несколько минут бэкапится.
95% вопросов уже обсуждались на форуме или ответы на них есть в мануале.        nnCron 1.93 b15.exe
Как правильно задавать вопросы.
User avatar
VoidVolker
Site Admin
 
Posts: 2898
Joined: Tue, 25 Apr 2006, 17:56

Re: Бэкап реестра Windows

Postby Morituruz » Fri, 28 Jun 2013, 09:01

VoidVolker wrote:А смысле бэкапа реестра-то? Нынче весь раздел с виндой в легкую за несколько минут бэкапится.

Этот вопрос выходит за рамки топика =-)
1. На разделе с виндой может быть много чего ещё, что не хотелось бы трогать, когда слетело несколько настроек реестра.
2. Бэкап раздела с виндой, даже инкрементный, весит гораздо больше, чем реестр в архивчике.
3. Реестр бэкапится на работающей системе.
User avatar
Morituruz
 
Posts: 727
Joined: Sun, 14 Oct 2007, 01:51


Return to nnCron forum (Russian)

Who is online

Users browsing this forum: No registered users and 1 guest