Отсылка письма средствами nnCron

Обсуждение программ nnCron и nnCron LITE

Re: Отсылка письма средствами nnCron

Postby AlikasS » Tue, 01 Sep 2009, 02:10

отлично отправляется с несколькими вложениями,

1.небольшой баг при сохранении и последующем открытии сохраненных писем,
приходилось добавлять перевод строки в следующих местах что бы были видны вложения при просмотре
Content-Type: multipart/mixed; boundary="bounds1"
<-- добавлен перевод строки
--bounds1
Content-Type: text/plain; charset=windows-1251
Content-Transfer-Encoding: quoted-printable
<-- добавлен перевод строки
--bounds1
Content-Type: plain/text;
name="filo.zip"
Content-transfer-encoding: base64
Content-Disposition: attachment;
filename="filo.zip"
<-- добавлен перевод строки
UEsDBBQAAAAIAMyJUzUtm
....

если вложенных файлов несколько то перевод строки нужен после каждого
filename=
2. в первой строке сохраненного файла просто слово DATE
вместо ожидаемого (что-то типа)
Date: Tue, 1 Sep 2009 10:58:55 +1100

P.S. сохраненный файл проверялся на TheBat, надо бы на остальных проверить...
и еще, про индентификатор программы,
предлагаю такой вариант:
S" X-Mailer: nncron.exe v %SVERSION% (SPF v %VERSION%)" EVAL-SUBST write \ Для nnCron
User avatar
AlikasS
 
Posts: 1434
Joined: Wed, 28 Jun 2006, 05:39
Location: Khabarovsk

Re: Отсылка письма средствами nnCron

Postby ndv » Thu, 17 Sep 2009, 09:00

Привет всем.
Кто сможет помочь?
Используем nncron для отслеживания изменений в каталоге. Применяем плагин из этой темы и скрипт отсюда же. Все работает. При изменении, появления или удаления файла приходит письмо.
Только нужно вместо приаттачивания определенного файла в теле письма указать имя (и относительный путь) изменившегося файла? Кто силен в скриптописании - подскажите пожалуйста.
ndv
 
Posts: 2
Joined: Wed, 16 Sep 2009, 16:48

Re: Отсылка письма средствами nnCron

Postby Ilya » Thu, 17 Sep 2009, 22:13

ndv wrote:Привет всем.
Кто сможет помочь?
Используем nncron для отслеживания изменений в каталоге. Применяем плагин из этой темы и скрипт отсюда же. Все работает. При изменении, появления или удаления файла приходит письмо.
Только нужно вместо приаттачивания определенного файла в теле письма указать имя (и относительный путь) изменившегося файла? Кто силен в скриптописании - подскажите пожалуйста.

Неполный (при удалении выдаст неправильное имя файла) вариант таков:
1) Подключаем files_pick.spf
2) И сам код
Code: Select all
#( test-dir
WatchDir: "e:\test"
Action:
RECENT-FILE-TIME: "e:\test\*.*" \

S" тема письма" \ тема
S" boss-pupkina@mailo.com" \ mail кому
S" pupkin@mailo.com" \ mail от кого
S" hMa1f7qzQcOq" \ логин
S" hLK4h1==" \ пароль
S" smtp.mailo.com" 25 \ адрес smtp сервера и порт
SMTP-SEND&ATTACH ?DUP IF MSG: "ошибка отправки: %0 esPICK%" ELSE MSG: "ОК" THEN

)#
Ilya
 
Posts: 443
Joined: Mon, 07 Aug 2006, 09:51
Location: Санкт-Петербург

Re: Отсылка письма средствами nnCron

Postby ndv » Fri, 18 Sep 2009, 08:25

Добрый день, Илья.

Подключил плагин и добавил строчку. При создании нового файла в каталоге, в сообщении отсутствует путь к файлу. А также после отправки сообщения, вываливается ошибка "Ошибка стека в Action:".
ndv
 
Posts: 2
Joined: Wed, 16 Sep 2009, 16:48

Re: Отсылка письма средствами nnCron

Postby Ilya » Fri, 18 Sep 2009, 10:58

ndv wrote:Добрый день, Илья.

Подключил плагин и добавил строчку. При создании нового файла в каталоге, в сообщении отсутствует путь к файлу. А также после отправки сообщения, вываливается ошибка "Ошибка стека в Action:".

Да, была ошибочка!
Обновлённый код плагина:
Code: Select all
\ smtp_nncron.f (адаптация под nnCron)
\ "Частичная" реализация протокола SMTP с возможностью аттача файлов

\ ADD-ATTACH ( adr n -- ) - Добавить путь к файлу в список

\ приоритеты письма
\ High-priority - высокий приоритет
\ Norm-priority - нормальный приоритет (по умолчанию)
\ Low-priority - низкий приоритет

\ подтверждения доставки и прочтения
\ Confirm-Reading - запрос подтверждения прочтения
\ Non-Confirm-Reading - нет запроса подтверждения прочтения (по умолчанию)

\ Confirm-Sending - запрос подтверждения доставки
\ Non-Confirm-Sending - нет запроса подтверждения доставки (по умолчанию)

\ адрес для обратного ответа установлен = адресу отправителя

\ установлен идентификатор почтовой программы

\ опционально, использование "условно-зашифрованного" логина в adr3-1 n3-1
\ для получения которого -> nncron.exe с ключом -ep <ваш_логин>
\ SECLOGINON \ SECLOGINOFF ( по умолчанию выключен)

\ опционально, использование "условно-зашифрованного" пароля в adr4 n4
\ для получения которого -> nncron.exe с ключом -ep <ваш_пароль>
\ SECPASSON \ SECPASSOFF ( по умолчанию выключен)


\ SMTP-SEND&ATTACH ( adr n adr1 n1 adr2 n2 adr3 n3 adr3-1 n3-1 adr4 n4 adr5 n5 -- err ) - собственно сама отправка

\ adr n     - содержимое письма
\ adr1 n1   - тема письма
\ adr2 n2   - кому!!!
\ adr3 n3   - от кого!!!
\ adr3-1 n3-1   - логин
\ adr4 n4   - пароль. Если пароль задать пустой строкой S" ", то аутентификация производится не будет (например для mail.ru)
\ adr5 n5   - адрес SMTP сервера
\ n6 - порт SMTP сервера
\ err       - 0 - зер гуд, иначе код ошибки


: CUR-DAY/TIME>S ( -- a u)
     GET-CUR-TIME
     Year@
     Mon@
     Day@
     Hour@
     Min@
     Sec@

    <#
       0 HOLD
       S" .eml" HOLDS
       S>D # # 2DROP
       S>D # # 2DROP
       S>D # # 2DROP
       S>D # # 2DROP
       S>D # # 2DROP
       S>D # # # #
\       ModuleDirName HOLDS
    #>
;

FALSE VALUE SMTPLOGF
FALSE VALUE SECLOGIN

\ Логирование вкл/выкл
: SMTPLOGON TRUE TO SMTPLOGF ;
: SMTPLOGOFF FALSE TO SMTPLOGF ;


: SECLOGINON TRUE TO SECLOGIN ;
: SECLOGINOFF FALSE TO SECLOGIN ;

FALSE VALUE SECPASS
: SECPASSON TRUE TO SECPASS ;
: SECPASSOFF FALSE TO SECPASS ;

3  VALUE X-Priority
: High-priority 2 TO X-Priority ;
: Norm-priority 3 TO X-Priority ;
: Low-priority 4 TO X-Priority ;

FALSE VALUE X-Confirm-Reading-To
: Confirm-Reading TRUE TO X-Confirm-Reading-To ;
: Non-Confirm-Reading FALSE TO X-Confirm-Reading-To ;

FALSE VALUE Return-Receipt-To
: Confirm-Sending TRUE TO Return-Receipt-To ;
: Non-Confirm-Sending FALSE TO Return-Receipt-To ;

VARIABLE attList    \ Указатель на список прикрепляемых файлов

\ Добавить путь к файлу в список
: ADD-ATTACH
        S>ZALLOC attList AddNode
;



: ?free ?DUP IF FREE THROW THEN ;

CREATE vName 255 ALLOT

CLASS: SMTP <SUPER POP3
        var vLogin
        var vFrom
        var vTo
        var vSubj
        var vData
        var vAttach
        var vErr
        var vFB
        var vlfh
        255 chars vBuf


DESTR: free
        vLogin @ ?free
        vFrom @ ?free
        vTo @ ?free
        vSubj @ ?free
        vlfh @ ?DUP IF CLOSE-FILE THROW THEN
        free
;

CONSTR: init
init
SMTPLOGF IF CUR-DAY/TIME>S R/W CREATE-FILE THROW vlfh ! THEN
;
M: Connect
vPort @ 0= IF 25 vPort ! THEN
Connect
;

M: smtpOK?
read DROP 3 S>NUM DUP
200 399 WITHIN IF DROP TRUE ELSE vErr ! FALSE THEN
;
M: Hello ( -- flag ) S" HELO localhost" write smtpOK? ;
M: Ehlo ( -- flag ) S" EHLO localhost" write HERE 1024 Read DROP  ( smtpOK?) TRUE ;
M: Auth ( -- flag )
S" AUTH LOGIN" write
read 2DROP
vLogin @ ASCIIZ>
SECLOGIN IF
        5 TO 64offset PAD debase64 2DUP + 0! 0 TO 64offset
THEN
HERE base64 write
read 2DROP
vPass @ ASCIIZ>
SECPASS IF
        5 TO 64offset PAD debase64 2DUP + 0! 0 TO 64offset
THEN
HERE base64 write
smtpOK?
;


M: Mail ( a n -- flag ) <# [CHAR] > HOLD vFrom @ ASCIIZ> HOLDS S" MAIL FROM: <" HOLDS 0#> write smtpOK? ;
M: Rcpt ( a n -- flag ) <# [CHAR] > HOLD vTo @ ASCIIZ> HOLDS S" RCPT TO: <" HOLDS 0#> write smtpOK? ;
M: write 2DUP SELF ->CLASS POP3 write SMTPLOGF IF vlfh @ WRITE-LINE THROW ELSE 2DROP THEN ;
M: sData ( adr n -- )   \ Начало передачи
S" DATA" write
smtpOK?
IF
        <# vFrom @ ASCIIZ> HOLDS S" From: " HOLDS 0#> write
        S" X-Priority: %X-Priority%" EVAL-SUBST write
        X-Confirm-Reading-To
        IF
                <# vFrom @ ASCIIZ> HOLDS S" X-Confirm-Reading-To: " HOLDS 0#> write
                <# vFrom @ ASCIIZ> HOLDS S" Disposition-Notification-To: " HOLDS 0#> write
        THEN

        Return-Receipt-To
        IF
                <# vFrom @ ASCIIZ> HOLDS S" Return-Receipt-To: " HOLDS 0#> write
        THEN

S" X-Mailer: nncron.exe v %VERSION%" EVAL-SUBST write    \ Для nnCron`
\ <# VERSION 1000 / S>D # # [CHAR] . HOLD # S" X-Mailer: spf4.exe v: " HOLDS #> write \ Для SPF4


<# vFrom @ ASCIIZ> HOLDS S" Reply-To: " HOLDS 0#> write

<# vTo @ ASCIIZ> HOLDS S" To: " HOLDS 0#> write
<# vSubj @ ASCIIZ> HOLDS S" Subject: " HOLDS 0#> write
S" MIME-Version: 1.0" write
S" Content-Type: multipart/mixed; boundary=%QUOTE%bounds1%QUOTE%" EVAL-SUBST write
S" --bounds1" write
S" Content-Type: text/plain; charset=windows-1251" write
S" Content-Transfer-Encoding: quoted-printable" write
SELF ->CLASS Socket WriteCRLF

OVER + SWAP
?DO
   S" =" SELF ->CLASS Socket Write
   I C@  N>H SELF ->CLASS Socket Write
LOOP
        SELF ->CLASS Socket WriteCRLF
ELSE 2DROP THEN
;

M: eData
S" --bounds1--" write
SELF ->CLASS Socket WriteCRLF S" ." write SELF ->CLASS Socket WriteCRLF
;

M: Data
sData eData
;

M: MyFILE \ { adr n -- }
  R/O OPEN-FILE-SHARED IF DROP S" " EXIT THEN  >R
  R@ FILE-SIZE THROW D>S DUP ALLOCATE THROW DUP vFB ! ( # a -- )
  DUP ROT R@ READ-FILE THROW
  R> CLOSE-FILE THROW
;

M: MyFILE-free
vFB @ ?DUP IF FREE THROW vFB 0! THEN
;


M: Data&Attach
sData
2DUP
ONLYNAME
vName ZPLACE
2DUP EXIST?
IF
        MyFILE
        S" --bounds1" write
        S" Content-Type: text/plain;" write
        S"  name=%QUOTE%%vName ASCIIZ>%%QUOTE%" EVAL-SUBST write
        S" Content-transfer-encoding: base64" write
        S" Content-Disposition: attachment;" write
        S"  filename=%QUOTE%%vName ASCIIZ>%%QUOTE%" EVAL-SUBST write
        SELF ->CLASS Socket WriteCRLF
        OVER + SWAP
        ?DO
                I 57 ( 76 )
                DUP 2* ALLOCATE THROW >R R@ base64 R> FREE DROP write
                57 ( 76 )
        +LOOP
ELSE 2DROP THEN

eData
MyFILE-free
;

M: _writeOneAttach
2DUP
ONLYNAME
vName ZPLACE
2DUP EXIST?
IF
        MyFILE
        S" --bounds1" write
        S" Content-Type: plain/text;" write
        S"  name=%QUOTE%%vName ASCIIZ>%%QUOTE%" EVAL-SUBST write
        S" Content-transfer-encoding: base64" write
        S" Content-Disposition: attachment;" write
        S"  filename=%QUOTE%%vName ASCIIZ>%%QUOTE%" EVAL-SUBST write
        SELF ->CLASS Socket WriteCRLF
        DUP ROT ROT
        OVER + SWAP
        ?DO
                DUP 57 ( 76 ) > IF I 57 ( 76 )  DUP 2* ALLOCATE THROW >R R@ base64 R> FREE DROP write ELSE I SWAP DUP 2* ALLOCATE THROW >R R@ base64 R> FREE DROP write LEAVE THEN
\         DUP 76 > IF I 76  vBuf base64 write ELSE I SWAP vBuf base64 write LEAVE THEN
\         DUP 76 > IF I 76  HERE base64 write ELSE I SWAP HERE base64 write LEAVE THEN
                57 ( 76 ) -
                57 ( 76 )
        +LOOP
ELSE 2DROP THEN
MyFILE-free
;

M: writeOneAttach NodeValue ASCIIZ> _writeOneAttach ;
M: free-node NodeValue FREE DROP ;

M: writeAttach
sData
   ['] writeOneAttach attList DoList
   ['] free-node attList DoList
   attList FreeList
eData
;

;CLASS



: SMTP-SEND&ATTACH { \ p -- }
SMTP NEW TO p

WITH SMTP
        p => vPort !
        p => Addr!
        S>ZALLOC p => vPass !
        S>ZALLOC p => vLogin !
        S>ZALLOC p => vFrom !
        S>ZALLOC p => vTo !
        S>ZALLOC p => vSubj !
[NONAME
        p => Create
        p => Connect
        p => read 2DROP
        p => vPass @ ASCIIZ> NIP
IF
        p => Ehlo
        p => Auth AND
ELSE
        p => Hello
THEN

IF
        p => Mail
        p => Rcpt
OR
IF p =>  writeAttach ELSE 2DROP 2DROP THEN
ELSE
    2DROP
THEN
NONAME] CATCH ?DUP IF p => vErr ! THEN
        p => Logout
        p => vErr @
        p => Delete
ENDWITH
;


ЗЫ У меня всё работает.
Ilya
 
Posts: 443
Joined: Mon, 07 Aug 2006, 09:51
Location: Санкт-Петербург

Re: Отсылка письма средствами nnCron

Postby Ilya » Fri, 18 Sep 2009, 16:23

ndv wrote:Добрый день, Илья.

Подключил плагин и добавил строчку. При создании нового файла в каталоге, в сообщении отсутствует путь к файлу. А также после отправки сообщения, вываливается ошибка "Ошибка стека в Action:".


Спецом для тебя:

1) Создаём файл watchdir.f содержащий код:
Code: Select all
\ Вотчим дирректорию на предмет изменения содержимого
\ REQUIRE CASE lib\ext\case.f
\ REQUIRE UNICODE>S ~nn\lib\unicode.f
WINAPI: ReadDirectoryChangesW kernel32.dll

1   CONSTANT   FILE_LIST_DIRECTORY
1   CONSTANT   FILE_NOTIFY_CHANGE_FILE_NAME
0x02000000   CONSTANT   FILE_FLAG_BACKUP_SEMANTICS

0
CELL   --   fniNextEntryOffset
CELL   --   fniAction
CELL   --   fniFileNameLength
CELL   --   fniFileName
CONSTANT   /FILE_NOTIFY_INFORMATION


USER-VALUE fnidir-handle
USER fnilpBytesReturned
USER-CREATE fni-buf 1024 ALLOT

: OPEN-DIR-SHARED ( c-addr u fam -- fileid ior )
  NIP SWAP >R >R
  0  FILE_FLAG_BACKUP_SEMANTICS ( template attrs )
  OPEN_EXISTING
  SA ( secur )
  3 ( share )
  R> FILE_LIST_DIRECTORY OR ( access=fam )
  R> ( filename )
  CreateFileA DUP -1 = IF GetLastError ELSE 0 THEN
;

: _READ-DIRECTORY-CHANGES
0 0
fnilpBytesReturned
0x5F
1
1024
fni-buf
fnidir-handle
ReadDirectoryChangesW
IF
   fni-buf fniFileName fni-buf fniFileNameLength @ UNICODE>S OVER >R
   HERE SWAP CMOVE R> FREE THROW
   HERE ASCIIZ>            \ Путь к файлу
   fni-buf fniAction @      \ Флаг события
ELSE
   S" "
   0
THEN
;

: WATCH-DIR ( adr n -- adr1 n1 flag )
\ adr n - путь к директории
\ adr1 n1 - путь к файлу
\ flag - 0 - нет такой директории
\ или
\ FILE_ACTION_ADDED, FILE_ACTION_REMOVED, FILE_ACTION_MODIFIED, FILE_ACTION_RENAMED_OLD_NAME, FILE_ACTION_RENAMED_NEW_NAME
R/O OPEN-DIR-SHARED
0= IF
   TO fnidir-handle
   _READ-DIRECTORY-CHANGES
   fnidir-handle CLOSE-FILE THROW
ELSE
   DROP S" " 0
THEN
;

2) Подключаем данный плагин.
3) Насколько я понял, то данное решение тебя устроит
Code: Select all
#( test-dir
CREATE zbuf 1024 ALLOT
: fniCaseFlagStr
   CASE
   1 OF S" создан"      ENDOF
   2 OF S" удалён"      ENDOF
   3 OF S" изменён"   ENDOF
   4 OF S" переименован" ENDOF
   5 OF S" переименован" ENDOF
   DROP S" " 0
   ENDCASE
;
SingleInstance
Action:
S" D:\croncheck" WATCH-DIR
fniCaseFlagStr
<# HOLDS S"  - " HOLDS HOLDS S" Изменения в каталоге произошли с " HOLDS 0. #>
zbuf ZPLACE
zbuf ASCIIZ>


S" Изменения в каталоге" \ тема
    S" user@mail.tld" \ mail кому
    S" check@mail.tld" \ mail от кого
    S" pupkin" \ логин
    S" " \ пароль
    S" mail.tld" 25 \ адрес smtp сервера и порт
    SMTP-SEND&ATTACH ?DUP IF MSG: "ошибка отправки: %0 esPICK%" ELSE MSG: "ОК" THEN

)#

Поправил в плагине маску фильтра событий
Ilya
 
Posts: 443
Joined: Mon, 07 Aug 2006, 09:51
Location: Санкт-Петербург

Re: Отсылка письма средствами nnCron

Postby Vitaly_st » Fri, 25 Sep 2009, 16:08

Ilya wrote:Да, была ошибочка!
Обновлённый код плагина:
ЗЫ У меня всё работает.


Как хочется, чтобы и у меня заработал плагин достойным образом!!!!
Скачал обновленный код, перегрузил программу, запустил файл *.xlsx 123202 байт, получаю *.xlsx 116717 байт!
Использую для решения задачи blat.exe, поэтому давно не заходил на форум, была надежда, что ситуация изменилась.
Vitaly_st
 
Posts: 24
Joined: Fri, 17 Jul 2009, 10:54

Re: Отсылка письма средствами nnCron

Postby Ilya » Fri, 25 Sep 2009, 19:11

Vitaly_st wrote:
Ilya wrote:Да, была ошибочка!
Обновлённый код плагина:
ЗЫ У меня всё работает.


Как хочется, чтобы и у меня заработал плагин достойным образом!!!!
Скачал обновленный код, перегрузил программу, запустил файл *.xlsx 123202 байт, получаю *.xlsx 116717 байт!
Использую для решения задачи blat.exe, поэтому давно не заходил на форум, была надежда, что ситуация изменилась.

Весьма странно! :(
Попробуй включить логирование (SMTPLOGON) и выслать мне исходник и лог-файл.
Ilya
 
Posts: 443
Joined: Mon, 07 Aug 2006, 09:51
Location: Санкт-Петербург

Re: Отсылка письма средствами nnCron

Postby Vitaly_st » Thu, 08 Oct 2009, 13:06

Ilya wrote:Как хочется, чтобы и у меня заработал плагин достойным образом!!!!
Скачал обновленный код, перегрузил программу, запустил файл *.xlsx 123202 байт, получаю *.xlsx 116717 байт!
Использую для решения задачи blat.exe, поэтому давно не заходил на форум, была надежда, что ситуация изменилась.

Весьма странно! :(
Попробуй включить логирование (SMTPLOGON) и выслать мне исходник и лог-файл.[/quote]
Code: Select all
NoActive
Action:
       \ 1.пример без шифрованного логина и пароля
        Low-priority \ низкий приоритет
        Confirm-Reading \ подтверждение прочтения
        Confirm-Sending \ подтверждение доставки
   SMTPLOGON
        S" c:\Program Files\nncron\plugins\other\smtp_nncron.f" ADD-ATTACH \ прикрепить файл
        S" текст письма" \ текст
        S" тема письма" \ тема
        S" boss@mail.ru" \ mail кому
        S" managr@mail.ru" \ mail от кого
        S" managr" \ логин
        S" pass" \ пароль
        S" smtp.mail.ru" 25 \ адрес smtp сервера и порт
        SMTP-SEND&ATTACH ?DUP IF MSG: "ошибка отправки: %0 esPICK%" ELSE MSG: "ОК" THEN

Думал, что придет сообщение на ответ в этой ветке форума, сообщение не пришло, а на форум не заходил, поэтому пытался достучаться по аське, но она постоянно выключена :)
Правильно включил логирование? Если да, где искать сам лог?
Vitaly_st
 
Posts: 24
Joined: Fri, 17 Jul 2009, 10:54

Re: Отсылка письма средствами nnCron

Postby Ilya » Thu, 08 Oct 2009, 18:29

Vitaly_st wrote:Думал, что придет сообщение на ответ в этой ветке форума, сообщение не пришло, а на форум не заходил, поэтому пытался достучаться по аське, но она постоянно выключена :)
Правильно включил логирование? Если да, где искать сам лог?

Включил правильно!
Логи должны лежать в папке nnCron-а. Файлы с расширением eml
Ilya
 
Posts: 443
Joined: Mon, 07 Aug 2006, 09:51
Location: Санкт-Петербург

Re: Отсылка письма средствами nnCron

Postby Ilya » Thu, 15 Oct 2009, 09:51

Победили ошибку на которую жаловался Vitaly_st.
Причины была в несвоевременном освобождении выделенной памяти
Code: Select all
FREE DROP write
(кто-то успевал залезть в неё перед write).
Плагин выложил в соотв. месте Отправка почты (e-mail) средствами nnCron
Ilya
 
Posts: 443
Joined: Mon, 07 Aug 2006, 09:51
Location: Санкт-Петербург

Re: Отсылка письма средствами nnCron

Postby AlikasS » Thu, 15 Oct 2009, 15:58

AlikasS wrote:отлично отправляется с несколькими вложениями,

1.небольшой баг при сохранении и последующем открытии сохраненных писем,
приходилось добавлять перевод строки в следующих местах что бы были видны вложения при просмотре
Content-Type: multipart/mixed; boundary="bounds1"
<-- добавлен перевод строки
--bounds1
Content-Type: text/plain; charset=windows-1251
Content-Transfer-Encoding: quoted-printable
<-- добавлен перевод строки
--bounds1
Content-Type: plain/text;
name="filo.zip"
Content-transfer-encoding: base64
Content-Disposition: attachment;
filename="filo.zip"
<-- добавлен перевод строки
UEsDBBQAAAAIAMyJUzUtm
....

если вложенных файлов несколько то перевод строки нужен после каждого
filename=
2. в первой строке сохраненного файла просто слово DATE
вместо ожидаемого (что-то типа)
Date: Tue, 1 Sep 2009 10:58:55 +1100

P.S. сохраненный файл проверялся на TheBat, надо бы на остальных проверить...
и еще, про индентификатор программы,
предлагаю такой вариант:
S" X-Mailer: nncron.exe v %SVERSION% (SPF v %VERSION%)" EVAL-SUBST write \ Для nnCron

Илья, эти моменты не смотрел?
User avatar
AlikasS
 
Posts: 1434
Joined: Wed, 28 Jun 2006, 05:39
Location: Khabarovsk

Re: Отсылка письма средствами nnCron

Postby Ilya » Thu, 15 Oct 2009, 16:57

AlikasS wrote:. . . . .
1.небольшой баг при сохранении и последующем открытии сохраненных писем,
приходилось добавлять перевод строки в следующих местах что бы были видны вложения при просмотре
. . . . .


Упустил! Сделаем!
Ilya
 
Posts: 443
Joined: Mon, 07 Aug 2006, 09:51
Location: Санкт-Петербург

Re: Отсылка письма средствами nnCron

Postby Vitaly_st » Wed, 21 Oct 2009, 12:05

Подскажите, как можно организовать рассылку по нескольким почтовым адресам? Возможна ли такая реализация в данном плагине? Спасибо!
Vitaly_st
 
Posts: 24
Joined: Fri, 17 Jul 2009, 10:54

Re: Отсылка письма средствами nnCron

Postby Ilya » Thu, 22 Oct 2009, 00:17

AlikasS wrote:......Илья, эти моменты не смотрел?

Посмотрел и вроде сделал!
Выложил в соотв. месте.
Ilya
 
Posts: 443
Joined: Mon, 07 Aug 2006, 09:51
Location: Санкт-Петербург

PreviousNext

Return to nnCron forum (Russian)

Who is online

Users browsing this forum: No registered users and 6 guests

cron