Готовые решения

[VoidVolker]

а почему он тогда нулевого размера и исчезает после выполнения задачи?

В случае ошибки ннкрон не удаляет этот файл и с его помощью можно определить причины.

И ещё, киньте плиз примеры, где *.fex работает. Мне он видится ограниченным по возможностям.

Возможности ровно те же, что и у самого ннкрона, кроме запуска задач по времени; доступен весь словарь ннкрона. Хотя ничто не мешает добавить задачу в реальном времени прямиком из скрипта. По-умолчанию плагины не погружаются - для скорости. Впрочем, ничто не мешает подгрузить плагины непосредственно в скрипте:

Code: Select all

S" M:\programms\nncron\plugins\tools.spf" INCLUDED

Зачем оно вообще нужно? Ну бывает нужно сделать простенький скриптик или поэкспериментировать - как раз самое то. Хотя сам-то как раз и не использую .

[ascerdfg1]

Code: Select all

#( miranda_IDLE
\  Когда после временного отсутствия за компом статус миранды переключается в "AWAY"
\  (настраивается в миранде), и далее по приходу к компу - миранда переключается
\  только в "ONLINE"! Я считаю это недостатком. Если хочется иной статус,
\  Например "FREE FOR CHAT", используем этот скрипт.
SingleInstance
Action:
BEGIN
  PAUSE: 3000
  WIN-EXIST: "Miranda"
   IF
     IDLE: 60
       IF
         BEGIN
           PAUSE: 2000
           IDLE: 3 NOT
             IF
               PAUSE: 3000
               WIN-EXIST: "Miranda"
                 IF
                   0 16595 273 WIN-HWND SendMessageA DROP \ изменяем статус на "FREE FOR CHAT" (число 16595 у всех разное, зависит от компоновки миранды, надо отлавливать)
                 THEN
             THEN
           IDLE: 60 NOT
         UNTIL
       THEN
   THEN
AGAIN
)#

[Fornit]

Для любителей качать аниме - его надо после скачивания проверять на CRC, дабы сбоев не было. А CRC обычно записан в конце имени файла, примерно так:
"[AonE-AnY]_Ah_My_Goddess_-_Sorezore_no_Tsubasa_-_05_[WS][F6808CCB].avi"

Так что я замутил скрипт:

Code: Select all

\ --- start of script file ----
CREATE file1 256 ALLOT
0 VALUE counter_var
: main

  get-string file1 PLACE
  S" CRC check is started in %ACTIVE-WINDOW%" CRON-LOG

  LOG: "crc_list.sfv" "; Generated by SFV32 v1.0a on %YYYY%-%MM%-%DD% at %hh%:%mm%.%ss%%crlf%"



  RE-ALL: "%file1 COUNT FILE%" "/(.*((\()|(\[))([a-fA-F0-9]{8})((\))|(\]))(\(.*\))?(\[AniDB\])?\.((avi)|(ogm)|(mkv)|(mp4)|(wmv)))/i"
\
\ "/(.*\.mkv) ([A-F0-9]{8})/i"               
\  "/^(.+\.mkv) ([A-F0-9]{8})$/i"

      LOG: "crc_list.sfv" "%$1% %$5%"
      counter_var 1+ TO counter_var

  ;RE-ALL

  S" CRC scan is finished. Total %counter_var% files." CRON-LOG
  TMSG: "Работа закончена!%crlf%Найдено и просканировано %counter_var% файлов." 3
  START-APPW: sfv32 -T -f "crc_list.sfv"
  QUERY: "All CRC Ok?" IF
    FILE-RENAME: "crc_list.sfv" "crc_ok.sfv"
  ELSE
    FILE-RENAME: "crc_list.sfv" "crc_ERROR.sfv"
  THEN

;
\ --- end of script file ------


Записываем скрипт в crc.tab и запускаем командой

5: CRC test for video from p2p.
dir /w /a-d /b /on > %TEMP%\filelist.tmp
"C:\Program Files (x86)\nnCron\nncron.exe" -runfile C:\Users\Fornit\AppData\Roaming\nnCron\crc.tab %TEMP%\filelist.tmp

Это кусок из меню в Far. Можно сделать батник.
Должна быть прога SFW32.EXE, которая и проверяет получившийся .sfv файл, сравнивая реальный CRC в файлах с заданным.

[Aveiro]

Доброго всем.Пару своих решений....Если "усушите" алгоритм буду рад
Простенькие вещи,но я пользую их .
Задача отсылки смс-ок из буфера обмена.

Code: Select all

#( SMS                                                                        \ задача: отсылка SMS из буфера обмена
NoActive
NoLog
 Action:
HOST-EXIST: "www.google.com"                                            \ проверка наличия Internet
  IF
    S" %DD%/%MM%/%YYYY% %hh%:%mm%:%ss% %CLIPBOARD%" EVAL-SUBST                \ текст       
    S" Acer"                                                                          \ тема
    S" 7909*******@sms.beemail.ru                                         \ mail кому     
    S" ******@mail.ru"                                                           \ mail от кого
    S" ******"                                                                        \ логин
    S" *******"                                                                      \ пароль
    S" smtp.mail.ru" 25                                                      \ адрес smtp сервера и порт
    SMTP-SEND&ATTACH ?DUP                                           \ отправка SMS
      IF
         0xFF00FF 0x00000000 HINT-COLOR S" Times New Roman" 20 HINT-FONT       \ если ошибка отправки SMS
         THINT: "Ошибка отправки SMS: %0 esPICK%" 5
      ELSE
         0x00FF7F 0x000000 HINT-COLOR S" Times New Roman" 20 HINT-FONT          \ если SMS отправлено     
         THINT: "SMS: ( %CLIPBOARD% ) отправлено" 5           
      THEN
  ELSE
      0xFF1493 0x000000 HINT-COLOR S" Times New Roman" 20 HINT-FONT              \ если отсутствует Internet
      THINT: "Нет Internet !  SMS не отправить" 5
  THEN

[Aveiro]

Иногда скапливается много окон,вот некоторые из них отправляю в трей...

Code: Select all

#( Активное_окно:_->_Tray_(Alt+1)                              \ задача: Активное окно сворачивается в трей
NoLog
WatchHotKey: "@1"                                              \ задача запускается при нажатии клавиш "Alt+1"
 Action:
HINT-POS: 0 0 0xEEE9BF 0x000000 HINT-COLOR S" Times New Roman" 20 HINT-FONT
THINT: "Окно: ( %ACTIVE-WINDOW% ) сворачивается в Tray " 3
  PAUSE: 2000
    WIN-TO-TRAY: %ACTIVE-WINDOW% PAUSE: 2000 TRAY-REFRESH      \ активное окно сворачивается в трей и трей обновляется
)#

[ascerdfg1]

Спасибо! ...Но всё равно билайн отстой и беспредельник. Это единственное его достоинство.

[Aveiro]

Мэй-би...
Главное работает,что не устраивает,так это иногда запаздывание в несколько часов с приемкой смс.....НО работает.

[AlikasS]

Иногда скапливается много окон,вот некоторые из них отправляю в трей...

Code: Select all

#( Активное_окно:_->_Tray_(Alt+1)                              \ задача: Активное окно сворачивается в трей
NoLog
WatchHotKey: "@1"                                              \ задача запускается при нажатии клавиш "Alt+1"
 Action:
HINT-POS: 0 0 0xEEE9BF 0x000000 HINT-COLOR S" Times New Roman" 20 HINT-FONT
THINT: "Окно: ( %ACTIVE-WINDOW% ) сворачивается в Tray " 3
  PAUSE: 2000
    WIN-TO-TRAY: %ACTIVE-WINDOW% PAUSE: 2000 TRAY-REFRESH      \ активное окно сворачивается в трей и трей обновляется
)#

...как прятать любое окно в трей, кликнув на кнопке Minimize правой кнопкой мыши?

[Aveiro]

Решение хорошее,как-то пропустил в Помощи, только одно но....это еще один довольно часто крутящейся цикл. А у меня их скопилось довольно много.Хотя nnCron вроде бережный растратчик ресурсов компа.

[ascerdfg1]

слова Watch... тоже крутящиеся.

[Aveiro]

AlikasS меня натолкнул на идею...
Сейчас делаю задачу ,чтобы одним циклом можно не только прятать окно в трей, а производить по нажатию правой и средней клавиш множество операций ( в зависимости куда подвели курсор). Почти готово...

[treo]

Хочу поделиться своими решениями. Правда они уже в блоге, поэтому делюсь ссылками на него
1. nnCron + nnBackup: самопальный TimeShift
2. nnCron: автоматизация SpeedyFox для Firefox
3. nnCron: запуск программы "горячей" клавишей
Все достаточно просто, если будут вопросы желательно писать их в блог.

[ascerdfg1]

Если nnCron запущен как служба, то головная боль с

Code: Select all

 Time: START-TIME

может решиться проще:

Code: Select all

#( start-time
 WatchProc: "Explorer.EXE"
SingleInstance
Action:
...
)#

У меня срабатывает устойчивее даже без AsLoggedUser, LoadProfile

[ascerdfg1]

С наступающими холодами важно не упустить слить воду из бочки в гараже. Это напоминалка, которая качает архив погоды из инета (линк нужно поменять для вашего региона) и находит минимальную температуру. Если она ниже установленной в этой задаче: (-?[0-3]), то выдаёт напоминание.

Code: Select all

#( water_tank
Time: 3 * * 9-3 * * \ каждый час с сентября по март
 Rule: ONLINE?
SingleInstance
Action:
FILE-EXIST: "water_tank.txt" NOT \ если не слил воду
  IF 
           S" http://rp5.ru/archive.php?wmo_id=27710&lang=ru" HTTP-GET 0=
              IF
                 S" water_tank.html" FWRITE \ сохраняю инет-страницу в файл
              ELSE 2DROP THEN
          FILE-EXIST: "water_tank.html"
             IF
                S" water_tank.html" FILE
                S" /(</div></td><td class=\x22cl_rd\w{0,3}\x22 nowrap=\x22nowrap\x22><div class=\x22t_0 dfs\x22 style=\x22display: inline;\x22>)(-?[0-3])\./" RE-MATCH \ "\ ищем температуру воздуха, кавычки "\x22"
                 IF
                   QUERY: "Воду слил? t*=%$2%*C"
                      IF FILE-CREATE: "water_tank.txt" 
                      THEN
                ELSE
                 \ MSG: "не слей"
                THEN
              FILE-DELETE: "water_tank.html" \ обязательно, для дополнительной проверки что http-get сработал
           ELSE
              MSG: "water_tank.html не найден"
           THEN
  ELSE \ MSG: "он слил воду"
  THEN
)#

#( water_tank-del \ чтобы активизировать напоминалку в следующем году
Time: 6 * * 4 * * \ каждый час в апреле чтобы уж точно стёрся этот файл, потому что мы можем уехать, заболеть, сломать комп, но не включать комп целый месяц это маловероятно
Action:
 FILE-DELETE: "water_tank.txt"
)#

[ascerdfg1]

Когда я ставлю греть молоко на газовой плите я забывал про него, поэтому сделал таймер (кнопка около газовой плиты подсоединённая ко входу LPT-порта + задача в ннКроне):

Code: Select all


#( lpt-input
WINAPI: DlPortWritePortUchar dlportio.dll
WINAPI: DlPortReadPortUchar dlportio.dll
SingleInstance
VARIABLE lpti
Action:
0 lpti !
BEGIN
 BEGIN
 1000 PAUSE
 0x379 DlPortReadPortUchar
 lpti !
 lpti @ 62 =
 UNTIL \ определяю момент включения газовой плиты
 PLAY-SOUND: "D:\WINDOWS\PIF\DING.WAV"
300000 PAUSE
 BEGIN
 PLAY-SOUND: "D:\WINDOWS\PIF\DING.WAV"
 TMSG: "ГАЗ НА ПЛИТЕ ГОРИТ 5 МИНУТ УЖЕ!" 2
 1000 PAUSE
 0x379 DlPortReadPortUchar
 lpti !
 lpti @ 126 =
 UNTIL \ пока не выключу газ и не отожму кнопку, будет надоедать сообщение
AGAIN
)#


Но потом я купил механический таймер и забил на эту задачу, о чём немного сожалею, ведь её можно было развить до двух-, трёх-кратного нажатия кнопки и другого, в зависимости от этого, времени выдержки.